IT備忘録

WindowsXPにおいて、ログインしているユーザーのデータバックアップを
するバッチです。
タスク機能を使い、定期的に実行したいのですが、ユーザー毎に実行ユーザーを
変更できないため、
１．マニュアルにて実行
２．ログオンバッチとして登録
３．グループポリシーにて、ログオン・ログオフ時に実行
を組み合わせて使おうかと考えています。
１台のＰＣを１人のみ使う場合は問題ないのですが。

-----
@echo off

REM ***********************************************
REM Initialize
REM ***********************************************
set BackUP-DRIVE=d:
set IME-VER=IMJP9_0
set UPDATE=update.txt

REM ***********************************************
REM Change to current folder
REM ***********************************************
%BackUP-DRIVE%
cd Backup

REM ***********************************************
REM New create a User folder
REM ***********************************************
if not exist %USERNAME% mkdir %USERNAME%
cd %USERNAME%

REM ***********************************************
REM Check to Back up folder
REM ***********************************************
if not exist "My Documents" mkdir "My Documents"
if not exist "Favorites" mkdir "Favorites"
if not exist "デスクトップ" mkdir "デスクトップ"
if not exist "Firefox" mkdir "Firefox"
if not exist "IME" mkdir "IME"

REM ***********************************************
REM Back up file
REM ***********************************************
xcopy "%USERPROFILE%\My Documents" "My Documents" /s /e /c /v /h /d /y
xcopy "%USERPROFILE%\Favorites" "Favorites" /s /e /c /v /h /d /y
xcopy "%USERPROFILE%\デスクトップ" "デスクトップ" /s /e /c /v /h /d /y
xcopy "%USERPROFILE%\Application Data\Mozilla\Firefox" "Firefox" /s /e /c /v /h /d /y
xcopy "%USERPROFILE%\Application Data\Microsoft\%IME-VER%\*" "IME" /s /e /c /v /h /d /y

REM ***********************************************
REM Get a Date & Time
REM ***********************************************
echo Last update day and time > %UPDATE%
date /t >> %UPDATE%
time /t >> %UPDATE%

REM ***********************************************
REM Change to ACL for user folder
REM ***********************************************
cd ..
cacls %USERNAME% /p %USERNAME%:f Administrator:f /t /c
-----

例）
このバッチをD:\Backup（任意のフォルダ）に保存して実行してみてください。